create zip file without .ds_store files??

[Oats]

I created a zip file using OS X, which is meant to be used cross-platform. I unzipped it in Windows, and I see all these ugly .DS_store and __MACOSX folders. I do not want these hidden files in my ZIP, since they are not hidden or useful for Windows.

Any tools or options I can use to not include these files when creating a ZIP?

[TheSpaz]

Use this Applescript in an Automator workflow and save the plug-in to the Finder to access it in the Finder contextual menu:

global parentFolder

set selUnixPaths to {}
set tempDir to quoted form of POSIX path of (path to temporary items folder as text)
set itemsUnixPaths to ""

tell application "Finder"
	set finderSelection to selection
	set parentFolder to (container of (item 1 of finderSelection as alias))
	if (length of finderSelection) > 1 then
		repeat with selectedItem in finderSelection
			copy quoted form of ("./" & (name of (selectedItem as alias))) to end of selUnixPaths
		end repeat
		repeat with selectedItem in selUnixPaths
			if itemsUnixPaths = "" then
				set itemsUnixPaths to selectedItem
			else
				set itemsUnixPaths to itemsUnixPaths & " " & selectedItem
			end if
		end repeat
		set archivename to my checkName("Archive.zip")
	else
		set itemsUnixPaths to quoted form of ("./" & name of (item 1 of finderSelection as alias))
		set namewitoutext to my trimext((item 1 of finderSelection) as alias)
		set archivename to my checkName(namewitoutext & ".zip")
	end if
end tell

set shellScript to "cd " & quoted form of (POSIX path of (parentFolder as alias)) & "; zip -b " & tempDir & " -9r '" & archivename & "' " & itemsUnixPaths & " -x *.DS_Store"

with timeout of 60 * 60 seconds
	do shell script shellScript
end timeout

on trimext(myfile)
	tell application "Finder"
		set fileextlenght to count of ((name extension of (myfile)) as text)
		set fileName to name of (myfile)
	end tell
	if fileextlenght > 0 then
		return (items 1 thru -(fileextlenght + 2) of fileName) as string
	else
		return fileName
	end if
end trimext

on checkName(archiveFile)
	tell application "Finder"
		if exists file (((parentFolder as alias) as string) & archiveFile) then
			set fileName to (items 1 thru -5 of archiveFile)
			set x to 2
			repeat while exists file (((parentFolder as alias) as string) & archiveFile)
				set archiveFile to fileName & " " & x & ".zip"
				set x to x + 1
			end repeat
		end if
		return archiveFile
	end tell
end checkName

Edit: You're welcome. I had to figure this out recently so it's great that you asked.

[Oats]

wow. that Automater script looks like a complete mess! it must have taken a long time. Automater has always been a mystery to me, and I am a programmer, so thats saying something. thanks so much for sharing this!

[TheSpaz]

Originally Posted by Oats

wow. that Automater script looks like a complete mess! it must have taken a long time. Automater has always been a mystery to me, and I am a programmer, so thats saying something. thanks so much for sharing this!

Hah. Sorry. I did not write the script but, it took some digging around to find it. And again, you're welcome.

[indiekiduk]

You can also use Stuffit in the contextual menu to archive to .zip, and in the settings you can choose to ignore finder files.

[okaki]

Or you can simply use "Yemuzip" available for free. You can choose to zip to "windows" style (yeah the first time ever mac sucks). The hidden files mac file system puts everywhere cause so much trouble especially when you just want to do a simple FTP transfer. Just a plain simple file transfer, my web server was ruined.

[pjrobertson]

Here's the automator workflow that I use. I'm not sure if it's a duplicate of TheSpaz's

http://mikepiontek.com/software/mac/...n-archive.html

[SC68Cal]

Why take sixty lines to do one simple command?

find ~ -name \.DS_Store -print0 | xargs -0 rm

[mnkeybsness]

I use the Terminal...

cd [directory]
zip -r [filename].zip *

Where directory is the directory you want to zip and filename is what you want the zip to be called. This will create the zip file inside of that folder that you just zipped.

[fulmar2]

Why use the terminal when you can use the finder?
Here is a simple drag-and-drop application that will
give you the zip files without the DS_Store and
__MACOSX.

[okaki]

But Yemuzip is for FREE!!!

Why use the terminal when you can use the finder?
Here is a simple drag-and-drop application that will
give you the zip files without the DS_Store and
__MACOSX.