Mac Mail: Notify if more than [n] CC recipients (to prevent Reply All embarrassment)

[I'mNotAMerryMan]

Hi, a friend of mine sometimes sends newsletter-type emails to a fair number of recipients. Usually he remembers to put them all in BCC but every now and then he accidentally puts them all in CC/TO instead. So people get angry (besides, my old iPhone takes ages to display mails where it has to render 500 mail addresses on top first, and I have to scroll until my thumb hurts before I can read the actual message).

Anyway, is there any plugin or Script trickery that might give a short notice if any message is addressed to more than say 10 people in CC? "Do you really want to do that?" But he doesn't want to switch mail clients / services (mailchimp, ...) so it would have to be on Mac Mail/Mavericks.

Many thanks!

 

[BrianBaughn]

I don't know of a way to do what you specifically asked.

Unless someone comes up with something you could always remove the "CC" field from the New Message toolbar and also, on both the Message Viewer and New Message windows, remove the default "Reply|Reply All|Forward" button and replace it with the separate "Reply" and "Forward" buttons.

This would force him to either enter a three-key combination or select a menu item to add CC recipients.

 

[I'mNotAMerryMan]

Hi Brian, thanks for replying. Unfortunately he's just as likely to use the TO field so your work-around won't complete avoid embarrassment ...

 

[0d085d]

Would a script that auto-populates the BCC field with addresses work? Then when he comes to address the message, he does it with a menu choice or key combination instead. Takes the opportunity to put them in the wrong box away from him, and also arguably saves him a step or two copying and pasting.

Mail doesn't have any capacity for third party hooks, so there isn't going to be anything you can do that doesn't involve some sort of change in his workflow. He's either going to need to remember to push a particular button or outright remember to use the BCC field.

 

[I'mNotAMerryMan]

Hi (mainly) Blue, that would work I guess. Do you know how this might be achieved? Thanks!

 

[0d085d]

If he makes a group in Contacts containing all of the people subscribed to the newsletter, something like this could work in Applescript:

set newsletterGroup to "Newsletter Subscribers" -- change this to the name of the group

set bccRecipients to {}
tell application "Contacts"
	set thePeople to people of group newsletterGroup
	repeat with aPerson in thePeople as list
		set emailAddress to value of (first email of aPerson)
		set the end of bccRecipients to emailAddress
	end repeat
	quit
end tell
tell application "Mail"
	set newMess to make new outgoing message at end of outgoing messages with properties {visible:true}
	tell newMess
		repeat with thisRecipient in bccRecipients as list
			make new bcc recipient at end of bcc recipients with properties {address:thisRecipient}
		end repeat
	end tell
end tell

Using the Script Editor application, save that in ~/Library/Scripts. While you're there, open preferences and tick the "Show script menu in menu bar" box. He can then run it from the scripts menu in the menu bar.

 

[I'mNotAMerryMan]

Beautiful, 0d085d, that works like a charm! Thank you so much!

All the best,
Harry