VIM Syntax Highlighting on MediaTemple Help (Ugh)

[turbobass]

Can't get this to work. Using homebrew on my Lion terminal.

I've done this:
http://kb.mediatemple.net/questions/1565/Enabling+vi+syntax+colors#gs

I've done the usual, which is to create a .vimrc and then use $VIMRUNTIME/vimrc_example.vim to write in the default VIM .vimrc file

I've set this up http://ricochen.wordpress.com/2011/07/23/mac-os-x-lion-terminal-color-remote-access-problem-fix/

which seems to have enabled some AWFUL colors in my ssh terminal (which I'd love to change)

And I've tried the simple :syntax on in VIM.

The best I get is some stuff underlined in VIM. I'd love to know how to get the full syntax highlighting working in VIM, and also to change the horrifying ~/.profile color (which I'll just turn off if I can't, no biggie).

Anyone want to point out where I've been a total dunce?

 

[mcq]

Ummm, well you said it ...

I'm not going to say you've been a "total dunce" but look at your own post. A shortened version of your message would be "I did everything the experts said to do so now tell me where they're all wrong."

You didn't actually show anything you did. There is a step between reading the expert help and reporting that it didn't work. When you undertake that step, you may have introduced a thing called error. Should I just enumerate all the possible errors or do you want to show them? Why not link to screenshots of what you've done instead of what other people told you to do?

Also, I'm not sure what you mean by "awful" colors. Check out http://vimcolorschemetest.googlecode.com and try to use words more neutral than "awful" to describe what you are getting.

Do any settings in your remote terminal and your local terminal differ? For instance, I have the following in .bashrc in both:
export TERM="xterm-256color"
export LS_COLORS='no=00:fi=00:di=38;5;197:ln=01;36i=40;33:so=01;35:bd=40;33;01:cd=40;33;01r=40;31;01:ex=01;33:*.tar=38;5;57:*.tgz=38;5;94:*.arj=38;5;94:*.taz=38;5;94:*.lzh=38;5;94:*.zip=38;5;94:*.z=38;5;94:*.Z=38;5;94:*.gz=38;5;94:*.bz2=38;5;94:*.deb=01;31:*.rpm=01;31:*.jpg=38;5;117:*.png=38;5;157:*.gif=01;35:*.bmp=01;35:*.ppm=01;35:*.tga=01;35:*.xbm=01;35:*.xpm=01;35:*.tif=01;35:*.mpg=01;35:*.avi=01;35:*.fli=01;35:*.gl=01;35:*.dl=01;35:*.tex=01;37:*.pdf=38;5;228:*.log=01;30:*.aux=01;30:*~=01;30:*.toc=01;30:*.bib=38;5;63:*.txt=01;29:*.dmg=38;5;94:*.html=38;5;140:*.mp4=38;5;60:*.mp3=38;5;220'
export CLICOLOR=true

But then again, if you correctly followed the tip you mentioned in "rico's tech memo" you may have already considered the possibility of conflicts on the remote host in various initialization files. This is the problem with giving advice where I don't know anything about what you actually did. I don't know what shell you're using on the remote host, so I don't even know if you should say export or set.

 

[turbobass]

You didn't actually show anything you did.

Apologies -- I am using my Lion Terminal.app to ssh into a friend's MediaTemple GridServer service so I thought this would be self-evident to anyone who had used the same service as I am using all of the defaults aside from the things I did that I linked to the descriptions of rather than post a million screens.

I don't have access to that setup atm but I do have the standard vimrc file below (that I used to test this) below.

I guess no one has gone down this road so I'll have to check and post again when I have access to this again with the details you've requested, thank you for taking the time to respond!

" An example for a vimrc file.
"
" Maintainer:	Bram Moolenaar <Bram@vim.org>
" Last change:	2008 Dec 17
"
" To use it, copy it to
"     for Unix and OS/2:  ~/.vimrc
"	      for Amiga:  s:.vimrc
"  for MS-DOS and Win32:  $VIM\_vimrc
"	    for OpenVMS:  sys$login:.vimrc

" When started as "evim", evim.vim will already have done these settings.
if v:progname =~? "evim"
  finish
endif

" Use Vim settings, rather than Vi settings (much better!).
" This must be first, because it changes other options as a side effect.
set nocompatible

" allow backspacing over everything in insert mode
set backspace=indent,eol,start

if has("vms")
  set nobackup		" do not keep a backup file, use versions instead
else
  set backup		" keep a backup file
endif
set history=50		" keep 50 lines of command line history
set ruler		" show the cursor position all the time
set showcmd		" display incomplete commands
set incsearch		" do incremental searching

" For Win32 GUI: remove 't' flag from 'guioptions': no tearoff menu entries
" let &guioptions = substitute(&guioptions, "t", "", "g")

" Don't use Ex mode, use Q for formatting
map Q gq

" CTRL-U in insert mode deletes a lot.  Use CTRL-G u to first break undo,
" so that you can undo CTRL-U after inserting a line break.
inoremap <C-U> <C-G>u<C-U>

" In many terminal emulators the mouse works just fine, thus enable it.
if has('mouse')
  set mouse=a
endif

" Switch syntax highlighting on, when the terminal has colors
" Also switch on highlighting the last used search pattern.
if &t_Co > 2 || has("gui_running")
  syntax on
  set hlsearch
endif

" Only do this part when compiled with support for autocommands.
if has("autocmd")

  " Enable file type detection.
  " Use the default filetype settings, so that mail gets 'tw' set to 72,
  " 'cindent' is on in C files, etc.
  " Also load indent files, to automatically do language-dependent indenting.
  filetype plugin indent on

  " Put these in an autocmd group, so that we can delete them easily.
  augroup vimrcEx
  au!

  " For all text files set 'textwidth' to 78 characters.
  autocmd FileType text setlocal textwidth=78

  " When editing a file, always jump to the last known cursor position.
  " Don't do it when the position is invalid or when inside an event handler
  " (happens when dropping a file on gvim).
  " Also don't do it when the mark is in the first line, that is the default
  " position when opening a file.
  autocmd BufReadPost *
    \ if line("'\"") > 1 && line("'\"") <= line("$") |
    \   exe "normal! g`\"" |
    \ endif

  augroup END

else

  set autoindent		" always set autoindenting on

endif " has("autocmd")

" Convenient command to see the difference between the current buffer and the
" file it was loaded from, thus the changes you made.
" Only define it when not defined already.
if !exists(":DiffOrig")
  command DiffOrig vert new | set bt=nofile | r # | 0d_ | diffthis
		  \ | wincmd p | diffthis
endif