Finder preferences beyond Advanced Settings??

Discussion in 'OS X Mavericks (10.9)' started by kirkbross, Feb 28, 2015.

  1. kirkbross macrumors 6502a

    kirkbross

    Joined:
    Mar 6, 2007
    Location:
    Los Angeles
    #1
    Every time I open a finder window (CMD+F) the Name column fills up the full width and I have to horizontal scroll to the right to see the rest of the columns.

    Is there any way to create and save a Finder config? The Advanced Settings in the Preferences is woefully inadequate. For the love of God...

    Here's what I'd like:

    Every time I open a finder I want the window to be X width and Y height and the Name column to be X width, and I want this, that and the other column to be X, Y & Z widths, and I never, ever, ever want a new Finder window to look differently. If I manually change it, I still want it to open with my fixed preferences, i.e. not open to the "last config."

    PS... I'm script and terminal savvy so whatever it takes to make this happen.
     
  2. kaibob, Feb 28, 2015
    Last edited: Mar 1, 2015

    kaibob macrumors regular

    Joined:
    Jun 21, 2010
    Location:
    Prescott, Arizona
    #2
    I researched this about a year ago and I was unable to find any way to set a configuration file as you want. I finally settled on a workaround, which was an Applescript I wrote. It was based, in part, on numerous such Applescripts that are available online.

    The Applescript I wrote (call it Finder Resize) sets window width and height. It also sets column widths--which in my case were name, modification date, size, and kind--and the width of the sidebar. After writing this script, I saved it as an application and control-dragged it to the Finder toolbar to create an icon.

    From that point, I frequently had to click on the Finder Resize icon when opening Finder but after a while Finder remembered the settings. Now, the only time I have to click on the Finder Resize icon is when I have manually changed a Finder window or column size.

    Clearly, this is a bit of a kludge, but it works quite well in my experience. If you are interested, let me know and I'll post the actual script.
     
  3. kirkbross thread starter macrumors 6502a

    kirkbross

    Joined:
    Mar 6, 2007
    Location:
    Los Angeles
    #3
    Please do! I'm very interested. I open a finder window and there is one column, Name, which takes up the entire width of the window, meanwhile size, type, date created are all off to the right and I have to scroll to see them. This is even if the names of my files / folders are short. It's completely useless.
     
  4. BrianBaughn macrumors 601

    BrianBaughn

    Joined:
    Feb 13, 2011
    Location:
    Baltimore, Maryland
    #4
    I made an app from a script like that and put it in my window toolbar.

    See this thread.
     
  5. kaibob, Mar 6, 2015
    Last edited: Mar 10, 2015

    kaibob macrumors regular

    Joined:
    Jun 21, 2010
    Location:
    Prescott, Arizona
    #5
    I have copied the script below. I believe the commenting is adequate to explain how it works.

    Initially, just to see how the script works, I suggest you set the Finder columns to Date Modified, Size, and Kind. As you are probably aware, this is done by right-clicking on the column headings in Finder.

    To use this script, copy and paste it into the Applescript Editor, save it as an application, and control-drag the application to the Finder toolbar to create an icon. Then, just click on the icon.

    Whenever you invoke this script, Finder will appear to momentarily blink. Applescript does not contain a refresh command for Finder, so the blink is actually the Finder window closing and opening. I couldn't find an alternative to this.

    I have used this script with Mavericks for over a year. I don't know if it will work with any other version of OS X.

    Code:
    --Set variables to width and height of Finder window.
    set w to 1180
    set h to 650
    
    --Set variable to width of sidebar.
    set s to 225
    
    --Set variables to column widths.
    set nameColumn to 300
    set dateColumn to 175
    set sizeColumn to 100
    set kindColumn to 210
    
    tell application "Finder"
    	
       --Set variable to current folder.
       set currentFolder to target of front Finder window
    	
       --Set variables to current position of upper-left corner of Finder window.
       set {x, y} to (get the position of front Finder window)
    	
       --Set width and height of Finder window.
       set the bounds of front Finder window to {x, y, x + w, y + h}
    	
       --Set width of Finder sidebar.
       set the sidebar width of the front Finder window to s
    	
       --Set width of Finder columns.
       tell list view options of front Finder window
          set the width of column id name column to nameColumn
          set the width of column id modification date column to dateColumn
          set the width of column id size column to sizeColumn
          set the width of column id kind column to kindColumn
       end tell
    	
       --Close and open Finder window to enable new settings.
       close front Finder window
       open currentFolder
    	
    end tell
     

Share This Page