on run -- example
set plistFile to (choose file) -- the plist file to use
set theKeys to {"showName", "videoURLString"} -- the keys to get values of
set X to 1 -- begin with the first array item
set theResult to {} -- this will be the values of the keys of the array items
repeat -- forever, or at least until there is an error in getting an element
try -- group the results - in this example, a list of lists of the key values
set keyItems to {} -- this will be the values of the keys in the current array item
repeat with aKey in theKeys
set end of keyItems to (getPlistElement from {plistFile, X, aKey})
end repeat
set end of theResult to keyItems
on error errmess
log errmess
exit repeat
end try
set X to X + 1 -- the next array item
end repeat
return theResult
end run
to getPlistElement from plistItems
(*
get the specified element from a simple plist structure by name or index
the number of items is not fixed, but must be at least 2 (the Plist file and a Plist element)
parameters: plistItems [list] -
item 1 [varies]: the plist file path
item 2 [varies]: the plist element name or index (names are case sensitive)
item(s) 3+ [varies]: sub item(s)
returns [mixed]: contents of the element
*)
try
if (count plistItems) is less than 2 then error "getPlistElement handler: item list contains too few items"
tell application "System Events"
set thePlistElement to property list file ((first item of plistItems) as text) -- start at the root element
repeat with anItem in rest of plistItems -- add on the sub items
set anItem to the contents of anItem
set thePlistElement to (get property list item anItem of thePlistElement)
end repeat
return value of thePlistElement
end tell
on error errorMessage number errorNumber
log errorMessage
error "getPlistElement handler: element not found (" & errorNumber & ")"
end try
end getPlistElement
