New help with Mac Folders

Discussion in 'Mac Basics and Help' started by kfmabey, Sep 22, 2014.

  1. kfmabey macrumors newbie

    Joined:
    Sep 22, 2014
    #1
    At an old job we had what I can at best describe as "Smart Folders". When we would have a new project, we would click the action drop down in finder and there would be an option to add a new folder that already had subfolders built into it:
    1_Assests
    2_Documents
    3_Drafts
    4_Working Files

    Can anyone help me figure out how I can do this? Thanks
     
  2. kryten2, Sep 22, 2014
    Last edited: Sep 22, 2014

    kryten2 macrumors 6502a

    Joined:
    Mar 17, 2012
    Location:
    Belgium
    #2
    You can do something similar with an Automator Service.

    In Automator :

    1. Choose to create a Service
    2. Service receives selected folders in application Finder
    3. Run AppleScript action with the following code :

      Code:
      on run {input, parameters}
      	tell application "Finder" to set finderIconPath to path to resource "Finder.icns"
      	set newFolderName to text returned of (display dialog "Enter a name for the new folder." default answer "New Folder name" with title "New Folder Name Dialog" buttons {"Cancel", "OK"} default button 2 with icon finderIconPath)
      	repeat with aFolder in input
      		tell application "Finder"
      			set newFolder to make new folder at aFolder with properties {name:newFolderName}
      			repeat with folderName in {"1_Assets", "2_Documents", "3_Drafts", "4_Working Files"}
      				make new folder at newFolder with properties {name:folderName}
      			end repeat
      		end tell
      	end repeat
      	--return input
      end run
    4. Save your Service e.g. New Folder with SubFolders

    Usage : Right click on folder(s) and select your Service in the Services pop up.
     

    Attached Files:

Share This Page